本文主要的目的是理解 dyld与objc是如何关联的

在上一篇文章iOS底层原理16：dyld源码分析中，我们探索了dyld的加载流程，最终会调用objc源码中的_objc_init方法

_objc_init 源码解析

首先，我们来看下libObjc中的_objc_init方法源码

void _objc_init(void)
{
    static bool initialized = false;
    if (initialized) return;
    initialized = true;
    
    // fixme defer initialization until an objc-using image is found?
    // 读取影响运行时的环境变量，如果需要，还可以打开环境变量帮助 export OBJC_HELP = 1
    environ_init();
    // 关于线程key的绑定，例如线程数据的析构函数
    tls_init();
    // 运行C++静态构造函数，在dyld调用我们的静态析构函数之前，libc会调用_objc_init先调用自己的C++构造函数
    static_init();
    // runtime运行时环境初始化，里面主要是unattachedCategories、allocatedClasses两张表的初始化
    runtime_init();
    // 初始化libObjc的异常处理系统
    exception_init();
#if __OBJC2__
    // 缓存条件初始化
    cache_t::init();
#endif
    // 启动回调机制。通常不会做什么，因为所有的初始化都是惰性的，但是对于某些进程，会迫不及待的加载trampolines dylib
    _imp_implementationWithBlock_init();

    /*
     _dyld_objc_notify_register -- dyld 注册的地方
     - 仅供objc运行时使用
     - 注册处理程序，以便在映射、取消映射 和初始化objc镜像文件时使用，dyld将使用包含objc_image_info的镜像文件数组，回调 mapped 函数
     
     map_images:dyld将image镜像文件加载进内存时，会触发该函数
     load_images：dyld初始化image会触发该函数
     unmap_image：dyld将image移除时会触发该函数
     */
    _dyld_objc_notify_register(&map_images, load_images, unmap_image);

#if __OBJC2__
    didCallDyldNotifyRegister = true;
#endif
}

根据源码可以看出，_objc_init主要有以下几个部分：

• environ_init：初始化一系列环境变量，并读取影响运行时的环境变量
• tls_init：关于线程key的绑定
• static_init：运行C++静态构造函数。在dyld调用我们的静态构造函数之前，libc会调用_objc_init先调用自己的C++构造函数
• runtime_init：runtime运行时环境初始化，里面主要是unattachedCategories、allocatedClasses两张表的初始化
• exception_init：初始化libObjc的异常处理系统
• cache_t::init：缓存条件初始化
• _imp_implementationWithBlock_init：启动回调机制。通常不会做什么，因为所有的初始化都是惰性的，但是对于某些进程，会迫不及待的加载trampolines dylib
• _dyld_objc_notify_register：dyld的注册

下面主要针对以上几部分配合源码进行说明

1、environ_init方法：环境变量初始化

void environ_init(void) 
{
    //...省略部分逻辑
    bool PrintHelp = false;
    bool PrintOptions = false;
    bool maybeMallocDebugging = false;

    // Scan environ[] directly instead of calling getenv() a lot.
    // This optimizes the case where none are set.
    for (char **p = *_NSGetEnviron(); *p != nil; p++) {
        //...省略部分逻辑
        if (0 == strncmp(*p, "OBJC_HELP=", 10)) {
            PrintHelp = true;
            continue;
        }
        if (0 == strncmp(*p, "OBJC_PRINT_OPTIONS=", 19)) {
            PrintOptions = true;
            continue;
        }
        //...省略部分逻辑
    }

    //...省略部分逻辑
    // Print OBJC_HELP and OBJC_PRINT_OPTIONS output.
    if (PrintHelp  ||  PrintOptions) {
        if (PrintHelp) {
            _objc_inform("Objective-C runtime debugging. Set variable=YES to enable.");
            _objc_inform("OBJC_HELP: describe available environment variables");
            if (PrintOptions) {
                _objc_inform("OBJC_HELP is set");
            }
            _objc_inform("OBJC_PRINT_OPTIONS: list which options are set");
        }
        if (PrintOptions) {
            _objc_inform("OBJC_PRINT_OPTIONS is set");
        }

        for (size_t i = 0; i < sizeof(Settings)/sizeof(Settings[0]); i++) {
            const option_t *opt = &Settings[i];            
            if (PrintHelp) _objc_inform("%s: %s", opt->env, opt->help);
            if (PrintOptions && *opt->var) _objc_inform("%s is set", opt->env);
        }
    }
}

从代码我们可以看出，只要我们在环境变量中配置了OBJC_HELP和OBJC_PRINT_OPTIONS，就会打印出相应的环境变量

• Xcode中设置环境变量OBJC_HELP和OBJC_PRINT_OPTIONS

image

image

• 通过终端命令export OBJC_HELP=1，查看环境变量

image

从上图我们可以看出有很多环境变量，其中常用的环境变量主要有以下几个（环境变量汇总见文末！）：

• DYLD_PRINT_STATISTICS：设置DYLD_PRINT_STATISTICS为YES，控制台就会打印 App 的加载时长，包括整体加载时长和动态库加载时长，即main函数之前的启动时间（查看pre-main耗时），可以通过设置了解其耗时部分，并对其进行启动优化。
• OBJC_DISABLE_NONPOINTER_ISA：杜绝生成相应的nonpointer isa（nonpointer isa指针地址 末尾为1），生成的都是普通的isa
• OBJC_PRINT_LOAD_METHODS：打印 Class 及 Category 的 + (void)load 方法的调用信息，包括动态库中的也会被打印
• NSDoubleLocalizedStrings：项目做国际化本地化(Localized)的时候是一个挺耗时的工作，想要检测国际化翻译好的语言文字UI会变成什么样子，可以指定这个启动项。可以设置 NSDoubleLocalizedStrings 为YES。
• NSShowNonLocalizedStrings：在完成国际化的时候，偶尔会有一些字符串没有做本地化，这时就可以设置NSShowNonLocalizedStrings 为YES，所有没有被本地化的字符串全都会变成大写。

环境变量 - OBJC_DISABLE_NONPOINTER_ISA

环境变量OBJC_DISABLE_NONPOINTER_ISA就是判断是否是优化的指针。YES表示纯指针，NO表示优化后的指针就是nonpointer isa。

• 未设置OBJC_DISABLE_NONPOINTER_ISA，对象的isa地址的二进制打印，末尾为1，表示isa不只是类对象地址，isa中包含了类信息、对象的引用计数等

image

• 设置OBJC_DISABLE_NONPOINTER_ISA环境变量为YES后，末尾变成了0，此时isa就是类的首地址，是一个纯的isa

image

环境变量 - OBJC_PRINT_LOAD_METHODS

• 配置打印load 方法的环境变量OBJC_PRINT_LOAD_METHODS，设置为YES

image

• 在HTPerson类中和NSObject+extension分类中重写+load函数，运行程序，load函数的打印如下

image

所以，OBJC_PRINT_LOAD_METHODS可以监控所有的+load方法（包括动态库），从而处理启动优化（后续会总结下启动优化方法）

2、tls_init：线程key的绑定

主要是本地线程池的初始化以及析构，源码如下

void tls_init(void)
{
#if SUPPORT_DIRECT_THREAD_KEYS // 本地线程池，用来进行处理
    pthread_key_init_np(TLS_DIRECT_KEY, &_objc_pthread_destroyspecific);
#else
    _objc_pthread_key = tls_create(&_objc_pthread_destroyspecific);
#endif
}

3、static_init：运行系统级别的C++静态构造函数

主要是运行系统级别的C++静态构造函数，在dyld调用我们的静态构造函数之前，libc调用_objc_init方法，即系统级别的C++构造函数 先于 自定义的C++构造函数 运行

static void static_init()
{
    size_t count;
    auto inits = getLibobjcInitializers(&_mh_dylib_header, &count);
    for (size_t i = 0; i < count; i++) {
        inits[i]();
    }
    auto offsets = getLibobjcInitializerOffsets(&_mh_dylib_header, &count);
    for (size_t i = 0; i < count; i++) {
        UnsignedInitializer init(offsets[I]);
        init();
    }
}

• 在objc4源码中定义c++构造函数，如下

__attribute__ ((constructor)) void htFunc() {
    printf("objc系统库-自定义构造函数：%s \n", __func__);
}

• 运行程序，在static_init中设置断点，看看是否会打印c++构造函数

image

从上图可以看出，libobjc系统库自己调用了内部的C++函数

4、runtime_init：运行时环境初始化

runtime运行时环境初始化，里面主要是unattachedCategories、allocatedClasses两张表的初始化

void runtime_init(void)
{
    objc::unattachedCategories.init(32);
    objc::allocatedClasses.init(); //初始化 -- 开辟的类的表
}

5、exception_init：初始化libobjc的异常处理系统

主要是初始化libobjc的异常处理系统，注册异常处理的回调，从而监控异常的处理，源码如下

/***********************************************************************
* exception_init
* Initialize libobjc's exception handling system.
* Called by map_images().
**********************************************************************/
void exception_init(void)
{
    old_terminate = std::set_terminate(&_objc_terminate);
}

• 当有crash（crash是指系统发生的不允许的一些指令，然后系统给的一些信号）发生时，会来到_objc_terminate方法，走到uncaught_handler扔出异常

/***********************************************************************
* _objc_terminate
* Custom std::terminate handler.
*
* The uncaught exception callback is implemented as a std::terminate handler. 
* 1. Check if there's an active exception
* 2. If so, check if it's an Objective-C exception
* 3. If so, call our registered callback with the object.
* 4. Finally, call the previous terminate handler.
**********************************************************************/
static void (*old_terminate)(void) = nil;
static void _objc_terminate(void)
{
    if (PrintExceptions) {
        _objc_inform("EXCEPTIONS: terminating");
    }

    if (! __cxa_current_exception_type()) {
        // No current exception.
        (*old_terminate)();
    }
    else {
        // There is a current exception. Check if it's an objc exception.
        @try {
            __cxa_rethrow();
        } @catch (id e) {
            // It's an objc object. Call Foundation's handler, if any.
            (*uncaught_handler)((id)e); // 抛出异常
            (*old_terminate)();
        } @catch (...) {
            // It's not an objc object. Continue to C++ terminate.
            (*old_terminate)();
        }
    }
}

• 全局搜索uncaught_handler，源码如下

/***********************************************************************
* objc_setUncaughtExceptionHandler
* Set a handler for uncaught Objective-C exceptions. 
* Returns the previous handler. 
**********************************************************************/
objc_uncaught_exception_handler 
objc_setUncaughtExceptionHandler(objc_uncaught_exception_handler fn)
{
    // fn为设置的异常句柄 传入的函数，为外界给的
    objc_uncaught_exception_handler result = uncaught_handler;
    uncaught_handler = fn;
    return result;
}

• 我们可以通过NSSetUncaughtExceptionHandler()方法，传入一个函数，用来处理异常

image

6、cache_t::init() 缓存初始化

void cache_t::init()
{
#if HAVE_TASK_RESTARTABLE_RANGES
    mach_msg_type_number_t count = 0;
    kern_return_t kr;

    while (objc_restartableRanges[count].location) {
        count++;
    }

    kr = task_restartable_ranges_register(mach_task_self(),
                                          objc_restartableRanges, count);
    if (kr == KERN_SUCCESS) return;
    _objc_fatal("task_restartable_ranges_register failed (result 0x%x: %s)",
                kr, mach_error_string(kr));
#endif // HAVE_TASK_RESTARTABLE_RANGES
}

7、_imp_implementationWithBlock_init：启动回调机制

启动回调机制。通常不会做什么，因为所有的初始化都是惰性的，但是对于某些进程，会迫不及待的加载trampolines dylib

void
_imp_implementationWithBlock_init(void)
{
#if TARGET_OS_OSX
    // Eagerly load libobjc-trampolines.dylib in certain processes. Some
    // programs (most notably QtWebEngineProcess used by older versions of
    // embedded Chromium) enable a highly restrictive sandbox profile which
    // blocks access to that dylib. If anything calls
    // imp_implementationWithBlock (as AppKit has started doing) then we'll
    // crash trying to load it. Loading it here sets it up before the sandbox
    // profile is enabled and blocks it.
    //
    // This fixes EA Origin (rdar://problem/50813789)
    // and Steam (rdar://problem/55286131)
    if (__progname &&
        (strcmp(__progname, "QtWebEngineProcess") == 0 ||
         strcmp(__progname, "Steam Helper") == 0)) {
        Trampolines.Initialize();
    }
#endif
}

8、_dyld_objc_notify_register：dyld注册

我们在上一篇中iOS底层原理16：dyld源码分析中，对这个方法已经进行过分析，其源码实现是在dyld源码中，以下是_dyld_objc_notify_register方法的声明

//
// Note: only for use by objc runtime
// Register handlers to be called when objc images are mapped, unmapped, and initialized.
// Dyld will call back the "mapped" function with an array of images that contain an objc-image-info section.
// Those images that are dylibs will have the ref-counts automatically bumped, so objc will no longer need to
// call dlopen() on them to keep them from being unloaded.  During the call to _dyld_objc_notify_register(),
// dyld will call the "mapped" function with already loaded objc images.  During any later dlopen() call,
// dyld will also call the "mapped" function.  Dyld will call the "init" function when dyld would be called
// initializers in that image.  This is when objc calls any +load methods in that image.
//
void _dyld_objc_notify_register(_dyld_objc_notify_mapped    mapped,
                                _dyld_objc_notify_init      init,
                                _dyld_objc_notify_unmapped  unmapped);

从方法的注释，可以得出：

• 仅供objc运行时使用
• 注册处理程序，以便在映射、取消映射和初始化objc图像时调用
• dyld将会通过一个包含objc-image-info的镜像文件的数组回调mapped函数

方法中的三个参数分别表示的含义如下：

• map_images：dyld将image（镜像文件）加载进内存时，会触发该函数
• load_image：dyld初始化image会触发该函数
• unmap_image：dyld将image移除时，会触发该函数

dyld与Objc的关联

• libObjc源码中的调用如下

_dyld_objc_notify_register(&map_images, load_images, unmap_image);

• _dyld_objc_notify_register方法的具体实现在 dyld源码中

void _dyld_objc_notify_register(_dyld_objc_notify_mapped    mapped,
                                _dyld_objc_notify_init      init,
                                _dyld_objc_notify_unmapped  unmapped)
{
    dyld::registerObjCNotifiers(mapped, init, unmapped);
}

• registerObjCNotifiers代码如下：

image

所以有以下等价关系

• sNotifyObjCMapped == mapped == map_images
• sNotifyObjCInit == init == load_images
• sNotifyObjCUnmapped == unmapped == unmap_image

load_images调用时机

在上篇文章中，我们知道了load_images是在notifySingle方法中执行的，调用情况如下：

image

map_images调用时机

关于load_images的调用时机已经在dyld加载流程中讲解过了，下面以map_images为例，看看其调用时机

• dyld源码中全局搜索sNotifyObjcMapped，在notifyBatchPartial方法中找到了调用

image

• 继续全局搜索notifyBatchPartial，在registerObjCNotifiers方法中调用

image

所以有以下结论：map_images是先于load_images调用，即先map_images ，再load_images

dyld与Objc的关联

结合dyld加载流程，dyld与Objc的关联如下图所示

image

• 在dyld中注册回调函数，可以理解为 添加观察者
• 在objc中dyld注册，可以理解为发送通知
• 触发回调，可以理解为执行通知selector

附录

环境变量汇总