Shaderlab Notizen 7-1 Standard Shader

一、Unity5中的Standard Shader

Unity5中重点推出了一套基于物理的着色（Physically Based Shading，PBS）的多功能Shader，叫做标准着色器（Standard Shader）。这套Shader的设计初衷是化繁为简。想用这样的一个多功能Shader，来代替之前多种多样的Shader各司其职，对于不同的材质效果，需要不同的Shader的局面。
Unity 5中目前有两个标准着色器，一个名为Standard，我们称它为标准着色器的标准版，另一个名为Standard（Specular Setup），我们称它为标准着色器的高光版，它们共同组成了一个完整的PBS光照明模型，且非常易于使用。其实这两个Shader基本差不多，只是有细微的属性参数上的区别。标准版这边的_Metallic（金属性）、_MetallicGlossMap（金属光泽贴图），被高光版的_SpecColor（高光颜色）、_SpecGlossMap（高光颜色法线贴图）所代替。
标准着色器主要是针对硬质表面（也就是建筑材质）而设计的，可以处理大多数现实世界的材质，例如石头、陶瓷、铜器、银器或橡胶等。同时，它也可以非常出色地处理一些非硬质表面的材质，例如皮肤、头发或布料等。

Unity5 Standard Shader的演示Demo
http://www.iqiyi.com/w_19rquxac31.html

1.1 Physically Based Shading（基于物理的着色）
基于物理的着色（Physically Based Shading，简称PBS）就是以某种方式模拟现实中材质和光照的相互作用的一种着色方法。这种方法在需要光照和材质更加直观和逼真地协同工作的场合下优势非常明显。基于物理的着色模拟了光线在现实中的行为，实现了在不同的光照条件下的逼真效果。为实现这种效果需要遵循各种物理原理，包括能量守恒（也就是物体反射出去的光量不可能超过所接收的光量），Fresnel反射（所有表面反射在掠射角（grazing angles）处更加强烈），以及物体表面是如何自我遮挡等原理。

ps：另一篇笔记

1.2 如何使用标准着色器
可以在Unity5中任意材质的Shader选项中的最前面看到两个Standard Shader字样的选项。其中第一个是普通版，第二个带Specularsetup是高光版。

标准着色器标准版材质界面：

Paste_Image.png

标准着色器的高光版材质界面：

Paste_Image.png

Unity官方文档：
http://docs.unity3d.com/Manual/shader-StandardShader.html

以及这里Unity5 Standard Shader的官方文档论坛翻译版：
http://forum.china.unity3d.com/thread-897-1-1.html

1.3 标准着色器的组成

Unity5中标准着色器的组成概括如下：

两个Shader源文件
七个CG头文件
一个脚本文件（用于自定义材质编辑器UI）

1.3.1 两个Shader源文件
Stardard.shader着色器源文件 - 标准着色器的标准版
StardardSpecular.shader着色器源文件 - 标准着色器的高光版

1.3.2 七个CG头文件

UnityStandardBRDF.cginc头文件-用于存放标准着色器处理BRDF材质属性相关的函数与宏
UnityStandardConfig.cginc头文件-用于存放标准着色器配置相关的代码（其实里面就几个宏）
UnityStandardCore.cginc头文件-用于存放标准着色器的主要代码（如顶点着色函数、片段着色函数等相关函数）
UnityStandardInput.cginc头文件-用于存放标准着色器输入结构相关的工具函数与宏
UnityStandardMeta.cginc头文件-用于存放标准着色器meta通道中会用到的工具函数与宏
UnityStandardShadow.cginc头文件-用于存放标准着色器阴影贴图采样相关的工具函数与宏
UnityStandardUtils.cginc头文件-用于存放标准着色器共用的一些工具函数

1.3.3 一个脚本文件
StandardShaderGUI.cs脚本文件——定义了特定的自定义编辑器UI界面
标准着色器对应材质的编辑器外观不同于一般的Shader，就是因为在Shader末尾书写了如下的代码：
//使用特定的自定义编辑器UI界面
CustomEditor "StandardShaderGUI"

二、Unity5标准着色器源代码剖析：架构分析

源码如下：

//-----------------------------------------------【Shader说明】---------------------------
//       Unity5.2.1 Built-in Standard Shader
//--------------------------------------------------------------------------------------------

Shader "Standard"
{
    //------------------------------------【属性值】------------------------------------
    Properties
    {
        //主颜色
        _Color("Color", Color) = (1,1,1,1)
        //主纹理
        _MainTex("Albedo", 2D) = "white" {}

        //Alpha剔除值
        _Cutoff("Alpha Cutoff", Range(0.0, 1.0)) = 0.5
        //平滑、光泽度
        _Glossiness("Smoothness", Range(0.0, 1.0)) = 0.5

        //金属性
        [Gamma] _Metallic("Metallic", Range(0.0, 1.0)) = 0.0
        //金属光泽纹理图
        _MetallicGlossMap("Metallic", 2D) = "white" {}

        //凹凸的尺度
        _BumpScale("Scale", Float) = 1.0
        //法线贴图
        _BumpMap("Normal Map", 2D) = "bump" {}

        //高度缩放尺度
        _Parallax ("Height Scale", Range (0.005, 0.08)) = 0.02
        //高度纹理图
        _ParallaxMap ("Height Map", 2D) = "black" {}

        //遮挡强度
        _OcclusionStrength("Strength", Range(0.0, 1.0)) = 1.0
        //遮挡纹理图
        _OcclusionMap("Occlusion", 2D) = "white" {}

        //自发光颜色
        _EmissionColor("Color", Color) = (0,0,0)
        //自发光纹理图
        _EmissionMap("Emission", 2D) = "white" {}

        //细节掩膜图
        _DetailMask("Detail Mask", 2D) = "white" {}

        //细节纹理图
        _DetailAlbedoMap("Detail Albedo x2", 2D) = "grey" {}
        //细节法线贴图尺度
        _DetailNormalMapScale("Scale", Float) = 1.0
        //细节法线贴图
        _DetailNormalMap("Normal Map", 2D) = "bump" {}

        //二级纹理的UV设置
        [Enum(UV0,0,UV1,1)] _UVSec ("UV Set for secondary textures", Float) = 0

        //混合状态的定义
        [HideInInspector] _Mode ("__mode", Float) = 0.0
        [HideInInspector] _SrcBlend ("__src", Float) = 1.0
        [HideInInspector] _DstBlend ("__dst", Float) = 0.0
        [HideInInspector] _ZWrite ("__zw", Float) = 1.0
    }

    //===========开始CG着色器语言编写模块===========
    CGINCLUDE
        //BRDF相关的一个宏
        #define UNITY_SETUP_BRDF_INPUT MetallicSetup
    //===========结束CG着色器语言编写模块===========
    ENDCG

    //------------------------------------【子着色器1】------------------------------------
    // 此子着色器用于Shader Model 3.0
    //----------------------------------------------------------------------------------------
    SubShader
    {
        //渲染类型设置：不透明
        Tags { "RenderType"="Opaque" "PerformanceChecks"="False" }

        //细节层次设为：300
        LOD 300

        //--------------------------------通道1-------------------------------
        // 正向基础渲染通道（Base forward pass）
        // 处理方向光，自发光，光照贴图等 ...
        Pass
        {
            //设置通道名称
            Name "FORWARD"

            //于通道标签中设置光照模型为ForwardBase，正向渲染基础通道
            Tags { "LightMode" = "ForwardBase" }

            //混合操作：源混合乘以目标混合
            Blend [_SrcBlend] [_DstBlend]
            // 根据_ZWrite参数，设置深度写入模式开关与否
            ZWrite [_ZWrite]

            //===========开启CG着色器语言编写模块===========
            CGPROGRAM

            //着色器编译目标：Model 3.0
            #pragma target 3.0

            //编译指令：不使用GLES渲染器编译
            #pragma exclude_renderers gles

            // ---------编译指令：着色器编译多样化--------
            #pragma shader_feature _NORMALMAP
            #pragma shader_feature _ _ALPHATEST_ON _ALPHABLEND_ON _ALPHAPREMULTIPLY_ON
            #pragma shader_feature _EMISSION
            #pragma shader_feature _METALLICGLOSSMAP
            #pragma shader_feature ___ _DETAIL_MULX2
            #pragma shader_feature _PARALLAXMAP

            //--------着色器编译多样化快捷指令------------
            //编译指令：编译正向渲染基础通道（用于正向渲染中，应用环境光照、主方向光照和顶点/球面调和光照）所需的所有变体。
            //这些变体用于处理不同的光照贴图类型、主要方向光源的阴影选项的开关与否
            #pragma multi_compile_fwdbase
            //编译指令：编译几个不同变种来处理不同类型的雾效(关闭/线性/指数/二阶指数/)
            #pragma multi_compile_fog

            //编译指令：告知编译器顶点和片段着色函数的名称
            #pragma vertex vertForwardBase
            #pragma fragment fragForwardBase

            //包含辅助CG头文件
            #include "UnityStandardCore.cginc"

            //===========结束CG着色器语言编写模块===========
            ENDCG
        }
        //--------------------------------通道2-------------------------------
        // 正向附加渲染通道（Additive forward pass）
        // 以每个光照一个通道的方式应用附加的逐像素光照
        Pass
        {
            //设置通道名称
            Name "FORWARD_DELTA"

            //于通道标签中设置光照模型为ForwardAdd，正向渲染附加通道
            Tags { "LightMode" = "ForwardAdd" }

            //混合操作：源混合乘以1
            Blend [_SrcBlend] One

            //附加通道中的雾效应该为黑色
            Fog { Color (0,0,0,0) }

            //关闭深度写入模式
            ZWrite Off
            //设置深度测试模式：小于等于
            ZTest LEqual

            //===========开启CG着色器语言编写模块===========
            CGPROGRAM

            //着色器编译目标：Model 3.0
            #pragma target 3.0
            //编译指令：不使用GLES渲染器编译
            #pragma exclude_renderers gles

            // ---------编译指令：着色器编译多样化--------
            #pragma shader_feature _NORMALMAP
            #pragma shader_feature _ _ALPHATEST_ON _ALPHABLEND_ON _ALPHAPREMULTIPLY_ON
            #pragma shader_feature _METALLICGLOSSMAP
            #pragma shader_feature ___ _DETAIL_MULX2
            #pragma shader_feature _PARALLAXMAP

            //--------使用Unity内置的着色器编译多样化快捷指令------------
            //编译指令：编译正向渲染基础通道所需的所有变体，但同时为上述通道的处理赋予了光照实时阴影的能力。
            #pragma multi_compile_fwdadd_fullshadows
            //编译指令：编译几个不同变种来处理不同类型的雾效(关闭/线性/指数/二阶指数/)
            #pragma multi_compile_fog

            //编译指令：告知编译器顶点和片段着色函数的名称
            #pragma vertex vertForwardAdd
            #pragma fragment fragForwardAdd

            //包含辅助CG头文件
            #include "UnityStandardCore.cginc"

            //===========结束CG着色器语言编写模块===========
            ENDCG
        }

        // --------------------------------通道3-------------------------------
        //  阴影渲染通道（Shadow Caster pass）
        //  将将物体的深度渲染到阴影贴图或深度纹理中
        Pass
        {
            //设置通道名称
            Name "ShadowCaster"
            //于通道标签中设置光照模型为ShadowCaster。
            //此光照模型代表着将物体的深度渲染到阴影贴图或深度纹理。
            Tags { "LightMode" = "ShadowCaster" }

            //开启深入写入模式
            ZWrite On
            //设置深度测试模式：小于等于
            ZTest LEqual

            //===========开启CG着色器语言编写模块===========
            CGPROGRAM

            //着色器编译目标：Model 3.0
            #pragma target 3.0

            //编译指令：不使用GLES渲染器编译
            #pragma exclude_renderers gles

            // ---------编译指令：着色器编译多样化--------
            #pragma shader_feature _ _ALPHATEST_ON _ALPHABLEND_ON _ALPHAPREMULTIPLY_ON

            //--------着色器编译多样化快捷指令------------
            //进行阴影投射相关的多着色器变体的编译
            #pragma multi_compile_shadowcaster

            //编译指令：告知编译器顶点和片段着色函数的名称
            #pragma vertex vertShadowCaster
            #pragma fragment fragShadowCaster

            //包含辅助CG头文件
            #include "UnityStandardShadow.cginc"

            //===========结束CG着色器语言编写模块===========
            ENDCG
        }

        // --------------------------------通道4-------------------------------
        //  延迟渲染通道（Deferred Render Pass）
        Pass
        {
            //设置通道名称
            Name "DEFERRED"
            //于通道标签中设置光照模型为Deferred，延迟渲染通道
            Tags { "LightMode" = "Deferred" }

            CGPROGRAM
            #pragma target 3.0
            // TEMPORARY: GLES2.0 temporarily disabled to prevent errors spam on devices without textureCubeLodEXT
            #pragma exclude_renderers nomrt gles

            //---------编译指令：着色器编译多样化（shader_feature）--------
            #pragma shader_feature _NORMALMAP
            #pragma shader_feature _ _ALPHATEST_ON _ALPHABLEND_ON _ALPHAPREMULTIPLY_ON
            #pragma shader_feature _EMISSION
            #pragma shader_feature _METALLICGLOSSMAP
            #pragma shader_feature ___ _DETAIL_MULX2
            #pragma shader_feature _PARALLAXMAP

            //---------编译指令：着色器编译多样化（multi_compile）--------
            #pragma multi_compile ___ UNITY_HDR_ON
            #pragma multi_compile LIGHTMAP_OFF LIGHTMAP_ON
            #pragma multi_compile DIRLIGHTMAP_OFF DIRLIGHTMAP_COMBINED DIRLIGHTMAP_SEPARATE
            #pragma multi_compile DYNAMICLIGHTMAP_OFF DYNAMICLIGHTMAP_ON

            //编译指令：告知编译器顶点和片段着色函数的名称
            #pragma vertex vertDeferred
            #pragma fragment fragDeferred

            //包含辅助CG头文件
            #include "UnityStandardCore.cginc"

            //===========结束CG着色器语言编写模块===========
            ENDCG
        }

        // --------------------------------通道5-------------------------------
        //元通道（Meta Pass）
        //为全局光照（GI），光照贴图等技术提取相关参数，如（emission, albedo等参数值）
        //此通道并不在常规的渲染过程中使用
        Pass
        {
            //设置通道名称
            Name "META"

            //于通道标签中设置光照模型为Meta
            //（截止2015年10月22日，Unity 5.2.1的官方文档中并没有收录此光照模型，应该是Unity官方的疏漏）
            Tags { "LightMode"="Meta" }
            //关闭剔除操作
            Cull Off

            //===========开启CG着色器语言编写模块===========
            CGPROGRAM

            //编译指令：告知编译器顶点和片段着色函数的名称
            #pragma vertex vert_meta
            #pragma fragment frag_meta

            //---------编译指令：着色器编译多样化--------
            #pragma shader_feature _EMISSION
            #pragma shader_feature _METALLICGLOSSMAP
            #pragma shader_feature ___ _DETAIL_MULX2

            //包含辅助CG头文件
            #include "UnityStandardMeta.cginc"

            //===========结束CG着色器语言编写模块===========
            ENDCG
        }
    }

    //------------------------------------【子着色器2】-----------------------------------
    // 此子着色器用于Shader Model 2.0
    //----------------------------------------------------------------------------------------
    SubShader
    {
        //渲染类型设置：不透明
        Tags { "RenderType"="Opaque" "PerformanceChecks"="False" }
        //细节层次设为：150
        LOD 150

        //--------------------------------通道1-------------------------------
        // 正向基础渲染通道（Base forward pass）
        // 处理方向光，自发光，光照贴图等 ...
        Pass
        {
            //设置通道名称
            Name "FORWARD"
            //于通道标签中设置光照模型为ForwardBase，正向渲染基础通道
            Tags { "LightMode" = "ForwardBase" }
            //混合操作：源混合乘以目标混合，即结果为两者的混合
            Blend [_SrcBlend] [_DstBlend]
            // 根据_ZWrite参数，设置深度写入模式开关与否
            ZWrite [_ZWrite]

            //===========开启CG着色器语言编写模块===========
            CGPROGRAM
            //着色器编译目标：Model 2.0
            #pragma target 2.0

            // ---------编译指令：着色器编译多样化--------
            #pragma shader_feature _NORMALMAP
            #pragma shader_feature _ _ALPHATEST_ON _ALPHABLEND_ON _ALPHAPREMULTIPLY_ON
            #pragma shader_feature _EMISSION
            #pragma shader_feature _METALLICGLOSSMAP
            #pragma shader_feature ___ _DETAIL_MULX2
            // SM2.0: NOT SUPPORTED shader_feature _PARALLAXMAP

            //跳过如下变体的编译，简化编译过程
            #pragma skip_variants SHADOWS_SOFT DIRLIGHTMAP_COMBINED DIRLIGHTMAP_SEPARATE

            //--------着色器编译多样化快捷指令------------
            #pragma multi_compile_fwdbase
            #pragma multi_compile_fog

            //编译指令：告知编译器顶点和片段着色函数的名称
            #pragma vertex vertForwardBase
            #pragma fragment fragForwardBase

            //包含辅助CG头文件
            #include "UnityStandardCore.cginc"

            //===========结束CG着色器语言编写模块===========
            ENDCG
        }

        //--------------------------------通道2-------------------------------
        // 正向附加渲染通道（Additive forward pass）
        // 以每个光照一个通道的方式应用附加的逐像素光照
        Pass
        {
            //设置通道名称
            Name "FORWARD_DELTA"

            //于通道标签中设置光照模型为ForwardAdd，正向渲染附加通道
            Tags { "LightMode" = "ForwardAdd" }

            //混合操作：源混合乘以1
            Blend [_SrcBlend] One

            //附加通道中的雾效应该为黑色
            Fog { Color (0,0,0,0) }

            //关闭深度写入模式
            ZWrite Off

            //设置深度测试模式：小于等于
            ZTest LEqual

            //===========开启CG着色器语言编写模块===========
            CGPROGRAM
            //着色器编译目标：Model 2.0
            #pragma target 2.0

            // ---------编译指令：着色器编译多样化--------
            #pragma shader_feature _NORMALMAP
            #pragma shader_feature _ _ALPHATEST_ON _ALPHABLEND_ON _ALPHAPREMULTIPLY_ON
            #pragma shader_feature _METALLICGLOSSMAP
            #pragma shader_feature ___ _DETAIL_MULX2

            //跳过一些变体的编译
            // SM2.0: NOT SUPPORTED shader_feature _PARALLAXMAP
            #pragma skip_variants SHADOWS_SOFT

            //--------使用Unity内置的着色器编译多样化快捷指令------------
            //编译指令：编译正向渲染基础通道所需的所有变体，但同时为上述通道的处理赋予了光照实时阴影的能力。
            #pragma multi_compile_fwdadd_fullshadows
            //编译指令：编译几个不同变种来处理不同类型的雾效(关闭/线性/指数/二阶指数/)
            #pragma multi_compile_fog

            //编译指令：告知编译器顶点和片段着色函数的名称
            #pragma vertex vertForwardAdd
            #pragma fragment fragForwardAdd

            //包含辅助CG头文件
            #include "UnityStandardCore.cginc"

            //===========结束CG着色器语言编写模块===========
            ENDCG
        }

        // --------------------------------通道3-------------------------------
        //  阴影渲染通道（Shadow Caster pass）
        //  将将物体的深度渲染到阴影贴图或深度纹理中
        Pass
        {
            //设置通道名称
            Name "ShadowCaster"

            //于通道标签中设置光照模型为ShadowCaster。
            //此光照模型代表着将物体的深度渲染到阴影贴图或深度纹理。
            Tags { "LightMode" = "ShadowCaster" }

            //开启深入写入模式
            ZWrite On

            //设置深度测试模式：小于等于
            ZTest LEqual

            //===========开启CG着色器语言编写模块===========
            CGPROGRAM
            //着色器编译目标：Model 2.0
            #pragma target 2.0

            //---------编译指令：着色器编译多样化（shader_feature）--------
            #pragma shader_feature _ _ALPHATEST_ON _ALPHABLEND_ON _ALPHAPREMULTIPLY_ON

            //编译指令：跳过某些变体的编译
            #pragma skip_variants SHADOWS_SOFT

            //快捷编译指令：进行阴影投射相关的多着色器变体的编译
            #pragma multi_compile_shadowcaster

            //编译指令：告知编译器顶点和片段着色函数的名称
            #pragma vertex vertShadowCaster
            #pragma fragment fragShadowCaster

            //包含辅助CG头文件
            #include "UnityStandardShadow.cginc"

            //===========结束CG着色器语言编写模块===========
            ENDCG
        }

        // --------------------------------通道4-------------------------------
        //元通道（Meta Pass）
        //为全局光照（GI），光照贴图等技术提取相关参数，如（emission, albedo等参数值）
        //此通道并不在常规的渲染过程中使用
        Pass
        {
            //设置通道名称
            Name "META"

            //于通道标签中设置光照模型为Meta
            //（截止2015年10月22日，Unity 5.2.1的官方文档中并没有收录此光照模型，应该是Unity官方的疏漏）
            Tags { "LightMode"="Meta" }
            //关闭剔除操作
            Cull Off

            //===========开启CG着色器语言编写模块===========
            CGPROGRAM

            //编译指令：告知编译器顶点和片段着色函数的名称
            #pragma vertex vert_meta
            #pragma fragment frag_meta

            //---------编译指令：着色器编译多样化--------
            #pragma shader_feature _EMISSION
            #pragma shader_feature _METALLICGLOSSMAP
            #pragma shader_feature ___ _DETAIL_MULX2

            //包含辅助CG头文件
            #include "UnityStandardMeta.cginc"

            //===========结束CG着色器语言编写模块===========
            ENDCG
        }
    }

    //回退Shader为顶点光照Shader
    FallBack "VertexLit"
    //使用特定的自定义编辑器UI界面
    CustomEditor "StandardShaderGUI"
}

标准着色器由两个SubShader组成。第一个SubShader用于处理Shader Model 3.0，有5个通道，第二个SubShader用于处理Shader Model 2.0, 有4个通道
详细的架构如下图:

Paste_Image.png

三、Deferred Render（延迟渲染）

Deferred Render和Deferred Shading有一点细微的差别。

Deferred Shading：将所有的Shading全部转到Deferred阶段进行。
Deferred Render：只是有选择地将Lighting转到Deferred阶段进行。

Unity中默认使用的是Deferred Shading。
而延迟渲染，一言以蔽之，就是将光照/渲染的计算延迟到第二步进行，避免多次渲染同一个像素，从而减少多余的计算操作，以提高渲染效率的一种先进的渲染方式。

延迟渲染最大的优势是可以实现同屏中数量众多的动态光源（十几到几十个），这在传统的渲染管线中是很难实现的。

更多延迟渲染的细节，这边不细说，只是提供一些链接，以作进一步了解延迟渲染的导论之用：

四、着色器编译多样化

Unity5中使用了一种被称为着色器编译多样化(Multiple shader program variants)的新技术，常被称为“megashaders”或“uber shaders”，并通过为每种情况提供不同的预处理指令来让着色器代码多次被编译来实现。
在Unity中，这可以通过#pragmamulti_compile或者#pragma shader_feature指令来在着色器代码段中实现。这种做法对表面着色器也可行。
在运行时，相应的着色器变体是从材质的关键词中取得的（Material.EnableKeyword和 DisableKeyword)，或者全局着色器关键词（Shader.EnableKeyword和 DisableKeyword）。

4.1 multi_compile用法简析
若我们定义如下指令：

#pragma multi_compile FANCY_STUFF_OFFFANCY_STUFF_ON

也就表示定义了两个变体：FANCY_STUFF_OFF和FANCY_STUFF_ON。在运行时，其中的一个将被激活，根据材质或者全局着色器关键词（#ifdef FANCY_STUFF_OFF之类的宏命令也可以）来确定激活哪个。若两个关键词都没有启用，那么将默认使用前一个选项，也就是关闭（OFF）的选项FANCY_STUFF_OFF。
ps：也可以存在超过两个关键字的multi_compile编译选项
举个栗子：如下代码将产生4种着色器的变体：

#pragma multi_compile SIMPLE_SHADINGBETTER_SHADING GOOD_SHADING BEST_SHADING

当#pragma multi_compile中存在所有名字都是下划线的一个指定段时，就表示需在没有预处理宏的情况下产生一个空的着色器变种。这种做法在着色器编写中比较常见，因为这样可以在不影响使用的情况下，避免使用两个关键词，这样就节省了一个变量个数的占用（下面会提到，Unity中关键词个数是有129个的数量限制的）。
再举个栗子：下面的指令将产生两个着色器变体；第一个没有定义，第二个定义为FOO_ON：

#pragma multi_compile __ FOO_ON

这样就省去了一个本来需要定义出来的 FOO_OFF（FOO_OFF没有定义，自然也不能使用），节省了一个关键词个数的占用。
若Shader中有如上定义，则可以使用#ifdef来进行判断：

#ifdef FOO_ON
//代码段1
#endif

根据上面已经定义过的FOO_ON，此#ifdef判断的结果为真，代码段1部分的代码就会被执行到。反之，若#pragma multi_compile __FOO_ON一句代码没有交代出来，那么代码段1部分的代码就不会被执行。

4.2 shader_feature和multi_compile之间的区别

//#pragma shader_feature 和#pragma multi_compile非常相似，
//唯一的区别在于采用了#pragmashader_feature语义的shader，
//在遇到不被使用的变体的时候，就不会将其编译到游戏中。
//所以，shader_feature中使得所有的设置到材质中的关键词都是有效的，
//而multi_compile指令将从全局代码里设置关键词。

ps：shader_feature还有一个仅仅含有一个关键字的快捷表达方式
举个栗子：

#pragma shader_feature FANCY_STUFF

此为#pragma shader_feature _ FANCY_STUFF的一个简写形式，其扩展出了两个着色器变体，第一种变体自然为不定此FANCY_STUFF变量（那么若在稍后的Shader代码中进行#ifdef FANCY_STUFF的判断，则结果为假），第二种变体为定义此FANCY_STUFF变量（此情况下#ifdef FANCY_STUFF的判断结果为真）。

4.3 多个multi_compile连用会造成指数级增长
可以提供多个multi_compile流水线，然后着色器的结果可以被编译为几个流水线的排列组合
举个栗子：

#pragma multi_compile A B C
#pragma multi_compile D E

第一行中有3种选项，第二行中有两种选项，那么进行排列组合，总共就会有六种选项(A+D, B+D, C+D, A+E, B+E, C+E)。
容易想到，一般每以个multi_compile流水线，都控制着着色器中某一单一的特性。请注意，着色器总量的增长速度是非常快的。
比如，10条包含两个特性的multi_compil指令，会得到2的10次方，也就是1024种不同的着色器变体。

4.4 关于Unity中的关键词限制Keyword limit
Unity中将关键词的数量限制在了128个之内（着色变量算作关键字），且其中有一些已经被Unity内置使用了，因此真正可以自定义使用关键词的数量是小于128个的。同时，关键词是在单个Unity项目中全局使用并计数的，所以在同一项目中存在的但没用到Shader也要考虑在内，不要合起来在数量上超出Unity的关键词数量限制。

4.5 Unity内置的快捷multi_compile指令
如下有Unity内置的几个着色器变体的快捷多编译指令，他们大多是应对Unity中不同的光线，阴影和光照贴图类型。详情见rendering pipeline 。

multi_compile_fwdbase - 此指令表示，编译正向基础渲染通道（用于正向渲染中，应用环境光照、主方向光照和顶点/球面调和光照(Spherical Harmonic Lighting)）所需的所有变体。这些变体用于处理不同的光照贴图类型、主要方向光源的阴影选项的开关与否。
multi_compile_fwdadd - 此指令表示，编译正向附加渲染通道（用于正向渲染中；以每个光照一个通道的方式应用附加的逐像素光照）所需的所有变体。这些变体用于处理光源的类型（方向光源、聚光灯或者点光源），且这些变种都包含纹理cookie。
multi_compile_fwdadd_fullshadows – 此指令和上面的正向渲染附加通道基本一致，但同时为上述通道的处理赋予了光照实时阴影的能力。
multi_compile_fog - 此指令表示，编译出几个不同的Shader变体来处理不同类型的雾效(关闭/线性/指数/二阶指数)（off/linear/exp/exp2).

4.6 使用指令跳过某些变体的编译

可以使用#pragmaskip_variants语句跳过其中一些的编译。
举个栗子：

#pragma multi_compile_fwdadd
// 将跳过所有使用"POINT"或 "POINT_COOKIE"的变体
#pragma skip_variants POINT POINT_COOKIE

最后编辑于：2017.12.04 06:09:13

人面猴
序言：七十年代末，一起剥皮案震惊了整个滨河市，随后出现的几起案子，更是在滨河造成了极大的恐慌，老刑警刘岩，带你破解...
沈念sama阅读 201,924评论 5赞 474
死咒
序言：滨河连续发生了三起死亡事件，死亡现场离奇诡异，居然都是意外死亡，警方通过查阅死者的电脑和手机，发现死者居然都...
沈念sama阅读 84,781评论 2赞 378
救了他两次的神仙让他今天三更去死
文/潘晓璐我一进店门，熙熙楼的掌柜王于贵愁眉苦脸地迎上来，“玉大人，你说我怎么就摊上这事。” “怎么了？”我有些...
开封第一讲书人阅读 148,813评论 0赞 335
道士缉凶录：失踪的卖姜人
文/不坏的土叔我叫张陵，是天一观的道长。经常有香客问我，道长，这世上最难降的妖魔是什么？我笑而不...
开封第一讲书人阅读 54,264评论 1赞 272
港岛之恋（遗憾婚礼）
正文为了忘掉前任，我火速办了婚礼，结果婚礼上，老公的妹妹穿的比我还像新娘。我一直安慰自己，他们只是感情好，可当我...
茶点故事阅读 63,273评论 5赞 363
恶毒庶女顶嫁案：这布局不是一般人想出来的
文/花漫我一把揭开白布。她就那样静静地躺着，像睡着了一般。火红的嫁衣衬着肌肤如雪。梳的纹丝不乱的头发上，一...
开封第一讲书人阅读 48,383评论 1赞 281
城市分裂传说
那天，我揣着相机与录音，去河边找鬼。笑死，一个胖子当着我的面吹牛，可吹牛的内容都是我干的。我是一名探鬼主播，决...
沈念sama阅读 37,800评论 3赞 393
双鸳鸯连环套：你想象不到人心有多黑
文/苍兰香墨我猛地睁开眼，长吁一口气：“原来是场噩梦啊……” “哼！你这毒妇竟也来了？” 一声冷哼从身侧响起，我...
开封第一讲书人阅读 36,482评论 0赞 256
万荣杀人案实录
序言：老挝万荣一对情侣失踪，失踪者是张志新（化名）和其女友刘颖，没想到半个月后，有当地人在树林里发现了一具尸体，经...
沈念sama阅读 40,673评论 1赞 295
护林员之死
正文独居荒郊野岭守林人离奇死亡，尸身上长有42处带血的脓包…… 初始之章·张勋以下内容为张勋视角年9月15日...
茶点故事阅读 35,497评论 2赞 318
白月光启示录
正文我和宋清朗相恋三年，在试婚纱的时候发现自己被绿了。大学时的朋友给我发了我未婚夫和他白月光在一起吃饭的照片。...
茶点故事阅读 37,545评论 1赞 329
活死人
序言：一个原本活蹦乱跳的男人离奇死亡，死状恐怖，灵堂内的尸体忽然破棺而出，到底是诈尸还是另有隐情，我是刑警宁泽，带...
沈念sama阅读 33,240评论 4赞 318
日本核电站爆炸内幕
正文年R本政府宣布，位于F岛的核电站，受9级特大地震影响，放射性物质发生泄漏。R本人自食恶果不足惜，却给世界环境...
茶点故事阅读 38,802评论 3赞 304
男人毒药：我在死后第九天来索命
文/蒙蒙一、第九天我趴在偏房一处隐蔽的房顶上张望。院中可真热闹，春花似锦、人声如沸。这庄子的主人今日做“春日...
开封第一讲书人阅读 29,866评论 0赞 19
一桩弑父案，背后竟有这般阴谋
文/苍兰香墨我抬头看了看天上的太阳。三九已至，却和暖如春，着一层夹袄步出监牢的瞬间，已是汗流浃背。一阵脚步声响...
开封第一讲书人阅读 31,101评论 1赞 258
情欲美人皮
我被黑心中介骗来泰国打工，没想到刚下飞机就差点儿被人妖公主榨干…… 1. 我叫王不留，地道东北人。一个月前我还...
沈念sama阅读 42,673评论 2赞 348
代替公主和亲
正文我出身青楼，却偏偏与公主长得像，于是被迫代替她去往敌国和亲。传闻我的和亲对象是个残疾皇子，可洞房花烛夜当晚...
茶点故事阅读 42,245评论 2赞 341

Shaderlab Notizen 7-1 Standard Shader

推荐阅读更多精彩内容