Oneswap项目在恒定函数做市商（Constant Function Market Maker，CFMM）模型的基础之上引入链上订单簿来改善自动做市商（Automated Market Maker，AMM）的交易体验。用户可以像中心化交易所那样进行挂单和撤单，链上的订单撮合逻辑会按照用户的挂单需求交替与交易池和订单簿中的对手单进行撮合，从而为用户提供最理想的平均成交价格。
UniswapV2版本上线了闪电贷FlashSwap的功能，该功能允许任何人在调用任意pair合约的swap方法时，可以先从Uniswap的交易池中借出一定数量的代币，从其他合约中进行套利，随后给pair返还足够的代币，最终实现近乎0成本的套利行为。
为了帮助用户更好地利用Uniswap的闪电贷功能从OneSwap的订单簿中套利，抹平Uniswap和Oneswap项目之间的价格差，我们提供了这份套利指南，并且部署好了所需的套利合约，用户只需在发现有套利空间的时候执行一次Uniswap的swap调用，即可从中获利。
1. 套利发现
假设UniswapV2的ABC/USDT交易对目前的交易池状态为（100ABC，40000USDT），同时Oneswap的ABC/USDT交易池状态为（100ABC，43000USDT），同时还存在其他无法与交易池成交的买卖单，即不高于430=43000/100价格的买单，和不低于430的卖单。此时，Uniswap的ABC/USDT交易对和Oneswap的ABC/USDT交易对之间存在较大价差，也就存在相应的套利空间。
2. swap
在发现了套利空间的存在之后，用户需要在链下自行计算本次需要借贷的代币种类和数量。
在本例中，用户需要从UniswapV2的ABC/USDT交易池中借出ABC，拿到Oneswap的ABC/USDT交易对市场中卖出，并将换回的USDT的一部分返还给Uniswap的ABC/USDT交易池，剩余的USDT即为本次交易的套利收益。假设用户经过计算后，决定从Uniswap的ABC/USDT交易池中借出10个ABC，然后按照如下参数调用UniswapV2Pair合约实例的swap方法：
// 假设在uniswap的ABC/USDT交易对中，ABC对应token0，USDT对应token1.
// 此处表示需要从pair中借出10个ABC，0个USDT
swap(10,0,flashSwapAddr,data)
复制代码
这里的flashSwapAddr为部署好的套利合约的地址，data为传给套利合约的参数，套利合约的介绍参见下一小节。
3. 套利合约
套利合约是事先部署好的帮助用户进行闪电贷套利的合约实现，它实现了UniswapV2所定义的如下接口，以供UniswapV2Pair在进行swap时对外部合约进行调用：
interface IUniswapV2Callee {
function uniswapV2Call(address sender, uint amount0, uint amount1, bytes calldata data) external;
}
复制代码
对于普通用户而言，需要了解的仅仅是在第二步中调用swap方法时传入的后两个参数：该合约的地址，以及data字段。data字节数组中编码了两个布尔类型的值（token0IsStock，isOnlySwap）。由于oneswap的工厂合约在创建交易对实例时，针对（ABC，USDT）代币对可以创建出四个交易对市场：（stock=ABC，money=USDT，不支持订单簿）、（stock=ABC，money=USDT，支持订单簿）、（stock=USDT，money=ABC，不支持订单簿）、（stock=USDT，money=ABC，支持订单簿），因此用户需要通过设定这两个布尔变量来指定自己的oneswap目标套利市场是哪个。
在拿到了这两个输入之后，套利合约就会尝试在目标市场进行市价交易，并计算交易后得到的token是否足以返还给UniswapV2的交易对。如果不够的话，整笔交易就会失败，反之，如果足够，则会将需要返还的token数量返还给UniswapV2的pair，剩余的token转给用户。
在此例中，假设用户给定的输入是（true,false）并且uniswap ABC/USDT 交易对的token0为ABC。套利合约将尝试从（stock=ABC，money=USDT，支持订单簿）的oneswap 交易对市场中添加出售10个ABC的市价单。由于订单簿市场的存在，在此无法预估10个ABC能够兑换出的USDT数量，但只要该数量能够超过需要返还给UniswapV2Pair ABC/USDT 合约实例的USDT数量，用户就可以从中获利。
最后，附上套利合约的源码以及发送swap交易的示例脚本，相关源码存储在目录下，供用户参考。
合约源码
套利合约源码如下，在ETH主网上的部署地址为（TODO）：
pragma solidity 0.6.12;
import './libraries/UniswapV2Library.sol';
import './interfaces/IUniswapV2Pair.sol';
import './interfaces/IOneswapPair.sol';
import './interfaces/IERC20.sol';
import './interfaces/IUniswapV2Factory.sol';
import './interfaces/IOneSwapFactory.sol';
import './interfaces/IWETH.sol';
struct PairInfo{
address token0;
address token1;
address token0ForOneswap;
address token1ForOneswap;
bool token0IsStock;
bool isOnlySwap;
}
contract FlashSwap {
// uniswap 工厂合约地址
address public immutable uniswapFactory;
// oneswap 工厂合约地址
address public immutable oneswapFactory;
// weth 地址
address public immutable weth;
event AmountReturn(address,address,uint256);
constructor(address _factory, address _oneswapFactory, address _weth) public {
uniswapFactory = _factory;
oneswapFactory = _oneswapFactory;
weth = _weth;
}
receive() external payable { }
function uniswapV2Call(address sender, uint amount0, uint amount1, bytes calldata data) external{
PairInfo memory pairInfo;
pairInfo.token0 = IUniswapV2Pair(msg.sender).token0();
pairInfo.token1 = IUniswapV2Pair(msg.sender).token1();
pairInfo.token0ForOneswap = (pairInfo.token0 == weth) ? address(0) : pairInfo.token0;
pairInfo.token1ForOneswap = (pairInfo.token1 == weth) ? address(0) : pairInfo.token1;
address uniswapPair = IUniswapV2Factory(uniswapFactory).getPair(pairInfo.token0,pairInfo.token1);
{
// 该调用必须由uniswap pair发起
assert(msg.sender == uniswapPair);
require(amount0 == 0 || amount1 == 0,'Either amount0 or amount1 should be zero'); // this strategy is unidirectional
}
address pairAddress;
{
// data参数用来帮助合约寻找用户套利的oneswap pair目标
(pairInfo.token0IsStock, pairInfo.isOnlySwap) = abi.decode(data,(bool,bool));
address stock = pairInfo.token0IsStock ? pairInfo.token0ForOneswap: pairInfo.token1ForOneswap;
address money = pairInfo.token0IsStock ? pairInfo.token1ForOneswap: pairInfo.token0ForOneswap;
pairAddress = IOneSwapFactory(oneswapFactory).tokensToPair(stock,money,pairInfo.isOnlySwap);
require(pairAddress != address(0), 'OneSwap Pair does not exist!');
}
IOneSwapPair pair = IOneSwapPair(pairAddress);
(uint reserve0,uint reserve1,) = IUniswapV2Pair(uniswapPair).getReserves();
if (amount0 > 0) {
// 如果借出的是token0，则在oneswap pair中添加市价单，将amount0数量的token0卖出，
// 并计算需要返还给uniswap pair的token1的最小数目
// 如果通过在oneswap pair出售token0获得的token1的数量大于以上计算的最小数目，
// 则将向uniswap pair返还该最小数目的token1，并将剩余数量的token1转给用户
_safeTransferWETHToETH(pairInfo.token0, pairAddress, amount0);
uint amountReceived = pair.addMarketOrder(pairInfo.token0ForOneswap,address(this),uint112(amount0));
uint amountRequired = UniswapV2Library.getAmountIn(amount0, reserve1, reserve0);
require(amountReceived > amountRequired,'No profit to earn');
_safeTransferETHToWETH(pairInfo.token1,msg.sender,amountRequired);
_safeTransfer(pairInfo.token1, sender,amountReceived - amountRequired);
emit AmountReturn(pairInfo.token1, sender, amountReceived - amountRequired);
} else {
// 如果借出的是token1，则在oneswap pair中添加市价单，将amount1数量的token1卖出，
// 并计算需要返还给uniswap pair的token0的最小数目
// 如果通过在oneswap pair出售token1获得的token0的数量大于以上计算的最小数目，
// 则将向uniswap pair返还该最小数目的token0，并将剩余数量的token0转给用户
_safeTransferWETHToETH(pairInfo.token1, pairAddress, amount1);
uint amountReceived = pair.addMarketOrder(pairInfo.token1ForOneswap,address(this),uint112(amount1));
uint amountRequired = UniswapV2Library.getAmountIn(amount1, reserve0, reserve1);
require(amountReceived > amountRequired,'No profit to earn');
_safeTransferETHToWETH(pairInfo.token0,msg.sender,amountRequired);
_safeTransfer(pairInfo.token0, sender, amountReceived - amountRequired);
emit AmountReturn(pairInfo.token0, sender, amountReceived - amountRequired);
}
}
function _safeTransferWETHToETH(address token, address to, uint amount) internal {
if (token == weth){
IWETH(weth).withdraw(amount);
_safeTransferETH(to,amount);
}else{
require(IERC20(token).transfer(to,amount),'ERC20 transfer failed');
}
}
function _safeTransferETHToWETH(address token, address to, uint amount) internal {
if (token == weth){
IWETH(weth).deposit{value:amount}();
require(IWETH(weth).transfer(to, amount),'WETH transfer failed');
}else{
require(IERC20(token).transfer(to,amount),'ERC20 transfer failed');
}
}
function _safeTransfer(address token, address to, uint amount) internal {
if (token == weth){
_safeTransferETH(to, amount);
}else{
require(IERC20(token).transfer(to,amount),'ERC20 transfer failed');
}
}
function _safeTransferETH(address to, uint value) internal {
(bool success,) = to.call{value:value}(new bytes(0));
require(success, 'ETH transfer failed');
}
}
复制代码
Web3脚本
发送swap交易的示例脚本如下：
const uniswapPair = artifacts.require('UniSwapV2Pair');
// 在使用时，用户需要替换为eth主网上相应的合约地址
const flashSwapAddr = '0x82c102D3f260216F8E57C161A8f6B9996Ca5B6d2';
const uniswapPairAddr = '0x5F6E9Ce32ab4821cB62B315361E7307Fb80EDc2a';
async function flashSwap(){
pair = await uniswapPair.at(uniswapPairAddr);
bytes = web3.eth.abi.encodeParameters(['bool','bool'],[true,false]);
result = await pair.swap(100,0,flashSwapAddr,bytes);
console.log(result.logs);
}
async function exit(){
process.exit(1);
}
module.exports = async function(){
await flashSwap();
await exit();
}
复制代码
原文：OneSwap Series 2 - How to configure smart contracts》 链接：medium.com/@OneSwap/ho…
翻译:OneSwap中文社区
